使用esttab按组生成汇总统计信息，其中包含平均差异和显着性的列

3 回答

• 3

  如果你仍然想使用esttab，你可以使用单元格和模式 . 可以使用以下代码复制原始帖子中的表：

  sysuse auto, clear
  
  eststo domestic: quietly estpost summarize ///
      price mpg weight headroom trunk if foreign == 0
  eststo foreign: quietly estpost summarize ///
      price mpg weight headroom trunk if foreign == 1
  eststo diff: quietly estpost ttest ///
      price mpg weight headroom trunk, by(foreign) unequal
  
  esttab domestic foreign diff, ///
  cells("mean(pattern(1 1 0) fmt(2)) sd(pattern(1 1 0)) b(star pattern(0 0 1) fmt(2)) t(pattern(0 0 1) par fmt(2))") ///
  label
  

  产量

  -----------------------------------------------------------------------------------------------------
                                (1)                       (2)                       (3)                
  
                               mean           sd         mean           sd            b               t
  -----------------------------------------------------------------------------------------------------
  Price                     6072.42      3097.10      6384.68      2621.92      -312.26         (-0.44)
  Mileage (mpg)               19.83         4.74        24.77         6.61        -4.95**       (-3.18)
  Weight (lbs.)             3317.12       695.36      2315.91       433.00      1001.21***       (7.50)
  Headroom (in.)               3.15         0.92         2.61         0.49         0.54**        (3.30)
  Trunk space (.. ft.)        14.75         4.31        11.41         3.22         3.34***       (3.67)
  -----------------------------------------------------------------------------------------------------
  Observations                   52                        22                        74                
  -----------------------------------------------------------------------------------------------------
  

  回复于 2024-05-14T07:57:04+08:00
• 1

  我没有 esttab 用 esttab （ estout 包来自 ssc ）这样做，但我有 listtab （也是 ssc ）和 postfile 的解决方案 . 这里的表与我上面提到的表略有不同，但是这种方法足够通用，你可以修改它以满足你的需要 .

  此解决方案还使用LaTeX的 booktabs 包 .

  /* data and variables */
  sysuse auto, clear
  local vars price mpg weight headroom trunk
  
  /* means */
  tempname postMeans
  tempfile means
  postfile `postMeans' ///
      str100 varname domesticMeans foreignMeans pMeans using "`means'", replace
  foreach v of local vars {
      local name: variable label `v'
      ttest `v', by(foreign)
      post `postMeans' ("`name'") (r(mu_1)) (r(mu_2)) (r(p))
  }
  postclose `postMeans'
  
  /* medians */
  tempname postMedians
  tempfile medians
  postfile `postMedians' ///
      domesticMedians foreignMedians pMedians using `medians', replace
  foreach v of local vars {
      summarize `v' if !foreign, detail
      local med1 = r(p50)
      summarize `v' if foreign, detail
      local med2 = r(p50)
      ranksum `v', by(foreign)
      local pval = 2 * (1 - normal(abs(r(z))))
      post `postMedians' (`med1') (`med2') (`pval')
  }
  postclose `postMedians'
  
  /* combine */
  use `means'
  merge 1:1 _n using `medians', nogenerate
  format *Means *Medians %9.3gc
  list
  
  /* make latex table */
  /* requires LaTeX package `booktabs` */
  listtab * using "Table.tex", ///
      rstyle(tabular) replace ///
      head("\begin{tabular}{lcccccc}" ///
      "\toprule" ///
      "& \multicolumn{3}{c}{Means} & \multicolumn{3}{c}{Medians} \\" ///
      "\cmidrule(lr){2-4} \cmidrule(lr){5-7}" ///
      "& Domestic & Foreign & \emph{p} & Domestic & Foreign & \emph{p}\\" ///
      "\midrule") ///
      foot("\bottomrule" "\end{tabular}")
  

  这产生以下结果 .

  

  回复于 2024-05-14T07:57:04+08:00
• 8

  选择的答案很好，但有点减少 . 只有estpost ttest才能达到相同的效果 .

  sysuse auto, clear
  estpost ttest price mpg weight headroom trunk, by(foreign)
  esttab, cells("mu_1 mu_2 b(star)"
  

  输出如下所示：

  mu_1          mu_2         b   
  
  c_score     43.33858    42.034       1.30458***
  nc_a4_17    4.007524    3.924623    .0829008*
  

  回复于 2024-05-14T07:57:04+08:00