如何将命令行参数传递给批处理文件？-Java 学习之路

979

我需要在运行时将id和密码传递给cmd（或bat）文件，而不是将它们硬编码到文件中 .

这是命令行的样子：

test.cmd admin P@55w0rd > test-log.txt

15 回答

FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

这将循环播放批处理参数（％*），或者引用它们，然后回显每个参数 .

回复于 2024-05-17T09:55:50+08:00

16
没有必要使它复杂化 . 它只是命令％1％2参数，例如，
```
@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause
```
“暂停”显示批处理文件已完成的操作，并等待您按下任意键 . 将其保存为Windows文件夹中的xx.bat .

要使用它，请键入，例如：
```
xx c:\f\30\*.* f:\sites\30
```
这个批处理文件负责所有必要的参数，比如只复制文件，更新等等 . 我在Windows之前使用过它 . 如果您希望在复制文件时看到这些文件的名称，请忽略 Q 参数 .
回复于 2024-05-17T09:55:50+08:00
127

是的，当使用 if 和 for 和帮派时，不要忘记使用像 %%1 这样的变量 .

如果您忘记了双 % ，那么您将替换（可能为null）命令行参数，您将收到一些非常令人困惑的错误消息 .

回复于 2024-05-17T09:55:50+08:00
2
另一个有用的提示是使用 %* 表示"all" . 例如：
```
echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*
```
当你运行：
```
test-command admin password foo bar
```
上面的批处理文件将运行：
```
fake-command /u admin /p password admin password foo bar
```
我的语法可能略有错误，但这是一般的想法 .
回复于 2024-05-17T09:55:50+08:00
8
我就是这样做的 .
```
@fake-command /u %1 /p %2
```
这是命令行的样子：
```
test.cmd admin P@55w0rd > test-log.txt
```
％1适用于第一个参数％2（这里是棘手的部分）适用于第二个参数 . 您最多可以以这种方式传递9个参数 .
回复于 2024-05-17T09:55:50+08:00
30
```
@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue
```
注意：如果 %1 包含在引号本身中，IF "%1"=="" 将导致问题 .

在这种情况下，请使用 IF [%1]==[] 或在NT 4（SP6）和更高版本中使用 IF "%~1"=="" .
回复于 2024-05-17T09:55:50+08:00
53
要在命令行中引用set变量，您需要使用“％a％”，例如：
```
set a=100 
      echo %a%  
      output = 100
```
注意：这适用于Windows 7专业版 .
回复于 2024-05-17T09:55:50+08:00
17
简单的解决方案（即使问题很旧）

Test1.bat
```
echo off
echo "Batch started"
set arg1=%1
echo "arg1 is %arg1%"
echo on
pause
```
CallTest1.bat
```
call "C:\Temp\Test1.bat" pass123
```
产量
```
YourLocalPath>call "C:\Temp\test.bat" pass123

YourLocalPath>echo off
"Batch started"
"arg1 is pass123"

YourLocalPath>pause
Press any key to continue . . .
```
WhereLocalPath是当前目录路径 .

为了简单起见，将命令参数存储在变量中并使用变量进行比较 .

它不仅易于编写，而且易于维护，因此如果以后其他人或您在很长一段时间后阅读您的脚本，它将很容易理解和维护 .

编写内联代码：请参阅其他答案 .
回复于 2024-05-17T09:55:50+08:00
3
创建一个新的批处理文件（例如：openclass.bat）并在文件中写入以下行：
```
java %~n1
```
然后将批处理文件放在system32文件夹中，转到Java类文件，右键单击，属性，打开...，然后找到批处理文件，选择它，那就是...

这个对我有用 .

PS：关闭Java类时，我无法找到关闭cmd窗口的方法 . 目前...
回复于 2024-05-17T09:55:50+08:00
80
受@Jon的answer elsewhere的启发，我制作了一个更通用的算法来提取命名参数，可选值和开关 .

我们假设我们要实现一个实用程序 foobar . 它需要一个初始命令 . 它有一个可选参数 --foo ，它带有一个可选值（当然不能是另一个参数）;如果值丢失，则默认为 default . 它还有一个可选参数 --bar ，它取一个必需的值 . 最后，它可以采用标志 --baz ，不允许任何值 . 哦，这些参数可以按任何顺序排列 .

换句话说，它看起来像这样：
```
foobar <command> [--foo [<fooval>]] [--bar <barval>] [--baz]
```
这是一个解决方案：
```
@ECHO OFF
SETLOCAL
REM FooBar parameter demo
REM By Garret Wilson

SET CMD=%~1

IF "%CMD%" == "" (
  GOTO usage
)
SET FOO=
SET DEFAULT_FOO=default
SET BAR=
SET BAZ=

SHIFT
:args
SET PARAM=%~1
SET ARG=%~2
IF "%PARAM%" == "--foo" (
  SHIFT
  IF NOT "%ARG%" == "" (
    IF NOT "%ARG:~0,2%" == "--" (
      SET FOO=%ARG%
      SHIFT
    ) ELSE (
      SET FOO=%DEFAULT_FOO%
    )
  ) ELSE (
    SET FOO=%DEFAULT_FOO%
  )
) ELSE IF "%PARAM%" == "--bar" (
  SHIFT
  IF NOT "%ARG%" == "" (
    SET BAR=%ARG%
    SHIFT
  ) ELSE (
    ECHO Missing bar value. 1>&2
    ECHO:
    GOTO usage
  )
) ELSE IF "%PARAM%" == "--baz" (
  SHIFT
  SET BAZ=true
) ELSE IF "%PARAM%" == "" (
  GOTO endargs
) ELSE (
  ECHO Unrecognized option %1. 1>&2
  ECHO:
  GOTO usage
)
GOTO args
:endargs

ECHO Command: %CMD%
IF NOT "%FOO%" == "" (
  ECHO Foo: %FOO%
)
IF NOT "%BAR%" == "" (
  ECHO Bar: %BAR%
)
IF "%BAZ%" == "true" (
  ECHO Baz
)

REM TODO do something with FOO, BAR, and/or BAZ
GOTO :eof

:usage
ECHO FooBar
ECHO Usage: foobar ^<command^> [--foo [^<fooval^>]] [--bar ^<barval^>] [--baz]
EXIT /B 1
```
- 使用 SETLOCAL 以便变量不会转义到调用环境中 .
- 如果有人在调用环境中定义变量，请不要忘记初始化变量 SET FOO= 等 .
- 使用 %~1 删除引号 .
- 使用 IF "%ARG%" == "" 而不是 IF [%ARG%] == [] ，因为 [ 和 ] 根本不会播放以空格结尾的值 .
- 即使你在 IF 块中 SHIFT ，当前的args如 %~1 也不会更新，因为它们是在解析 IF 时确定的 . 您可以在 IF 块中使用 %~1 和 %~2 ，但这会让您感到困惑，因为您有 SHIFT . 为了清楚起见，您可以将 SHIFT 放在块的末尾，但这可能会丢失和/或混淆人们 . 所以"capturing" %~1 和 %~1 在街区之外似乎是最好的 .
- 你没有't want to use a parameter in place of another parameter'的可选值，所以你必须检查 IF NOT "%ARG:~0,2%" == "--" .
- 使用其中一个参数时，请注意 SHIFT .
- 重复的代码 SET FOO=%DEFAULT_FOO% 是令人遗憾的，但另一种方法是在 IF NOT "%ARG%" == "" 块之外添加 IF "%FOO%" == "" SET FOO=%DEFAULT_FOO% . 但是因为它仍然在 IF "%PARAM%" == "--foo" 块中，所以 %FOO% 值在您进入块之前已经被评估和设置，因此您永远不会检测到 --foo 参数都存在，并且还缺少 %FOO% 值 .
- 请注意 ECHO Missing bar value. 1>&2 将错误消息发送给stderr .
- 想要Windows批处理文件中的空行？你必须使用 ECHO: 或其中一个变体 .
回复于 2024-05-17T09:55:50+08:00
864
我写了一个简单的read_params脚本，可以作为函数（或外部 .bat ）调用，并将所有变量放入当前环境 . 它不会修改原始参数，因为该函数正在使用原始参数的副本进行编辑 .

例如，给定以下命令：
```
myscript.bat some -random=43 extra -greeting="hello world" fluff
```
myscript.bat 可以在调用函数后使用变量：
```
call :read_params %*

echo %random%
echo %greeting%
```
这是功能：
```
:read_params
if not %1/==/ (
    if not "%__var%"=="" (
        if not "%__var:~0,1%"=="-" (
            endlocal
            goto read_params
        )
        endlocal & set %__var:~1%=%~1
    ) else (
        setlocal & set __var=%~1
    )
    shift
    goto read_params
)
exit /B
```
Limitations
- 无法加载没有值的参数，例如 -force . 你可以使用 -force=true ，但我可以't think of a way to allow blank values without knowing a list of parameters ahead of time that won't有一个值 .
Changelog
- 2/18/2016
- 不再需要延迟扩展
- 现在通过在参数之前查找 - 来使用其他命令行参数 .
回复于 2024-05-17T09:55:50+08:00

让我们保持这个简单 .

这是.cmd文件 .

@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%

这是来自命令行的3个调用 .

C:\Users\joeco>echo_3params 1abc 2 def  3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def

C:\Users\joeco>echo_3params 1abc "2 def"  "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"

C:\Users\joeco>echo_3params 1abc '2 def'  "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'

C:\Users\joeco>

回复于 2024-05-17T09:55:50+08:00

48
使用％1，％2，...％9或％*可以轻松访问批处理参数，
但只有内容很简单 .

对于像 "&"^& 这样的复杂内容没有简单的方法，因为在不产生错误的情况下无法访问％1 .
```
set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"
```
线条扩展到
```
set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"
```
并且每一行都失败了，因为其中一个 & 在引号之外 .

它可以通过从临时文件读取 remarked 版本的参数来解决 .
```
@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'
```
诀窍是启用 echo on 并在 rem 语句之后展开％1（也适用于 %2 .. %* ） .
因此，即使是 "&"& 也可以在没有产生错误的情况下得到回应 .

但是为了能够重定向 echo on 的输出，您需要两个for循环 .

额外的字符 * # 用于对像 /? 这样的内容安全（会显示 REM 的帮助） .
或者，行尾的插入符^可以作为多行字符，即使在 rem 之后也是如此 .

然后从文件中读取 rem parameter 输出，但要小心 .
FOR / F应该与延迟扩展一起使用，否则"!"的内容将被销毁 .
删除 param1 中的多余字符后，你就明白了 .

要以安全的方式使用 param1 ，请启用延迟扩展 .
回复于 2024-05-17T09:55:50+08:00

如果您想要智能地处理缺失的参数，您可以执行以下操作：

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1

回复于 2024-05-17T09:55:50+08:00

243

一位朋友最近问我这个问题，所以我想我会发布如何处理批处理文件中的命令行参数 .

正如您所看到的，这种技术有一些开销，但它使我的批处理文件非常易于理解和快速实现 . 除了支持以下结构：

>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]

它的主旨是 :init ， :parse 和 :main 函数 .

示例用法

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

template.bat

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof

回复于 2024-05-17T09:55:50+08:00

如何将命令行参数传递给批处理文件？

15 回答

相关问题