附加到outlook模板的VBA打开工作簿

1 回答

• 0

  我假设您从Excel自动化Outlook . 此解决方案可能适合您，但正如您所说，它确实依赖于保存附件并重新附加文件的操作版本 . 假设您可以编写将工作簿附件"edit"的代码，这应该适合您 .

  Sub TestOutlookTemplate()
  
  Dim MyOutlook As Outlook.Application
  Dim MyMail As Outlook.MailItem
  Dim att As Outlook.Attachment
  Dim templatePath As String
  Dim tempFileName As String
  Dim attWorkbook As Workbook
  
  
  templatePath = "C:\users\david_zemens\desktop\Untitled.oft"
  tempFileName = "C:\users\david_zemens\desktop\tempexcelfile.xlsx"
  
  Set MyOutlook = CreateObject("Outlook.Application")
  
  Set MyMail = MyOutlook.CreateItemFromTemplate(templatePath)
      MyMail.Display
  
      For Each att In MyMail.Attachments
          If att.DisplayName Like "*.xls*" Then
              att.SaveAsFile tempFileName
  
              'Now that you have saved the file, delete the attachment
              att.Delete
  
              'Open the file
              Set attWorkbook = Workbooks.Open(tempFileName)
  
              'Perform manipulation on the file
              attWorkbook.Sheets(1).Name = "Sheet ONE"
  
              'Save fhe file
              attWorkbook.Save
  
              'Close the file
              attWorkbook.Close
  
              MyMail.Attachments.Add tempFileName
          End If
      Next
  
  
  'Send your mail (make sure you have added a recipient
  MyMail.Send
  
  Set attWorkbook = Nothing
  Set MyMail = Nothing
  Set MyOutlook = Nothing
  
  
  End Sub
  

  回复于 2024-04-28T15:50:05+08:00