表示Haskell中的四面体数字序列-Java 学习之路

我一直想要学习一些Haskell，我知道它和类似的语言对各种无限列表都有很好的支持 . 那么，我怎样才能在Haskell中表示四面体数的序列，最好解释一下发生了什么？

0   0   0
1   1   1
2   3   4
3   6   10
4   10  20
5   15  35
6   21  56
7   28  84
8   36  120

如果不清楚那里发生了什么，第二列是第一列的运行总计，第三列是第二列的运行总计 . 我更喜欢Haskell代码保留一些“运行总计”的方法，因为这是我想知道如何表达的概念 .

2 回答

10
你是对的，Haskell非常适合做这样的事情：
```
first_col = [0..]
second_col = scanl1 (+) first_col
third_col = scanl1 (+) second_col
```
- first_col 是一个无限的整数列表，从0开始
- scanl (+) 计算一个懒惰的运行总和：Prelude docs
我们可以验证上面的代码是做正确的事情：
```
Prelude> take 10 first_col 
[0,1,2,3,4,5,6,7,8,9]
Prelude> take 10 second_col 
[0,1,3,6,10,15,21,28,36,45]
Prelude> take 10 third_col 
[0,1,4,10,20,35,56,84,120,165]
```
回复于 2024-04-29T17:34:04+08:00
6
除了perimosocordiae的最佳答案之外，像Haskell这样的语言非常灵活，它们允许您创建无限列表的无限列表 .

首先让我们定义生成每个连续行的运算符：
```
op :: [Integer] -> [Integer]
op = scanl1 (+)
```
正如perimosocordiae所解释的，这只是一个懒惰的运行总和 .

我们还需要一个基本案例：
```
tnBase :: [Integer]
tnBase = [0..]
```
那么我们如何得到无限的四面体数列表？我们在基本情况下迭代此操作，然后在基本情况下产生输出，然后输出...
```
tn = iterate op tnBase
```
iterate 在Prelude中，可以使用hoogle和searching by name（如果你有一个好的猜测）或type signature（你通常知道你需要的签名）找到这样的功能 . Source code通常链接自haddock documentation .

Presentation

（如果你对 Map ，拍摄，掉落和头部感到不舒服）

这一切都很好，但是如果你不知道如何通过第一个无限列表来查看第二个，第三个等等，那就没用了 . 有很多选项，只需要获得一个特定的列表就可以放弃第一个几个：
```
getNthTN n = head (drop n tn)
```
获取每个列表的前几个结果可能更符合您的要求：
```
printFirstFew n m = print $ take m (map (take n) tn)
```
这里 map (take n) tn 将从每个四面体数列表中获取第一个 n 值，而 take m 将我们的结果限制在第一个 m 列表中 .

最后，我喜欢用于快速交互式播放数据的精彩groom包：
```
> groom $ take 10 (map (take 10) tn)
[[0, 1, 2, 3, 4, 5, 6, 7, 8, 9],
 [0, 1, 3, 6, 10, 15, 21, 28, 36, 45],
 [0, 1, 4, 10, 20, 35, 56, 84, 120, 165],
 [0, 1, 5, 15, 35, 70, 126, 210, 330, 495],
 [0, 1, 6, 21, 56, 126, 252, 462, 792, 1287],
 [0, 1, 7, 28, 84, 210, 462, 924, 1716, 3003],
 [0, 1, 8, 36, 120, 330, 792, 1716, 3432, 6435],
 [0, 1, 9, 45, 165, 495, 1287, 3003, 6435, 12870],
 [0, 1, 10, 55, 220, 715, 2002, 5005, 11440, 24310],
 [0, 1, 11, 66, 286, 1001, 3003, 8008, 19448, 43758]]
```
回复于 2024-04-29T17:34:04+08:00

表示Haskell中的四面体数字序列

2 回答

相关问题