通过CMake实现Qt项目

2 回答

• 64

  您的脚本有几个错误，也可以改进一些事情 . 更改后it will be看起来像：

  cmake_minimum_required(VERSION 3.0.2)
  project(MyProject)
  
  find_package(Qt5Widgets)
  
  set(CMAKE_AUTOMOC ON)
  set(CMAKE_AUTOUIC ON)
  set(CMAKE_INCLUDE_CURRENT_DIR ON)
  
  add_library(mainwindow mainwindow.cpp)
  target_link_libraries (mainwindow Qt5::Widgets)
  
  add_executable(MyProject main.cpp)
  target_link_libraries (MyProject mainwindow)
  

  Errors ：

  • 错误的 add_executable 指令 . 您尝试添加库，但为此您需要使用 target_link_libraries . 所以代替：

  add_executable(Cmake main.cpp mainwindow)
  

  你需要：

  add_executable(Cmake main.cpp)
  target_link_libraries (Cmake mainwindow)
  

  • 还有一个错误是缺少 add_library 指令中的 *.cpp 文件：

  add_library(mainwindow mainwindow.cpp ${Cmake_hdr_moc} ${Cmake_form_hdr})

  Recomendations ：

  • 同样设置 CMake 的版本也是合适的 . 如果您使用 CMAKE_AUTOMOC ，则需要的版本不低于2.8.6，如果使用 CMAKE_AUTOUIC ，则需要的版本不低于3.0.2：

  cmake_minimum_required(VERSION 3.0.2)
  

  • 不需要使用 qt5_wrap_cpp 和 CMAKE_AUTOMOC .

  • 当你使用 CMAKE_AUTOMOC 使用 CMAKE_AUTOUIC 而不是 qt5_wrap_ui 时会更合适 .

  • 此脚本适用于文件系统中具有以下结构的项目：

  Project
  ├── CMakeLists.txt
  ├── main.cpp
  ├── mainwindow.cpp
  ├── mainwindow.h
  └── mainwindow.ui
  

  如果你有另一个结构，你应该使用@steveire提到的 include_directories .

  • （ UPD ）因为，我写过这个答案，我为尝试与 Qt 通过 CMake 见面的初学者多次提出过建议 . 他们抱怨该项目名称不合适 - "Cmake" . 对于刚刚遇到 CMake 的初学者来说，很难意识到cmake - 只是项目名称的一部分（并非强制性的），而cmake是指令的一部分（并且是强制性的） . 所以我想将项目名称从"Cmake"替换为"MyProject" . 这减少了问题和答案之间的联系，但另一方面，这使得答案对初学者更友好 .

  • （ UPD ）正如@ErikSjölund提到的那样 qt5_use_modules is obsolete和 target_link_libraries 应该用来代替 .

  Note ：我个人对 CMAKE_AUTOMOC 有过不成功的经历;当我的包含文件存储在单独的目录中时，'s good for simple project with plain structure. I'已经出现问题：

  .
  ├── include
  │   └── QtClass.h
  └── src
      └── QtClass.cpp
  

  当具有相同名称的文件进入不同的子目录时：

  .
  ├── NamespaceA
  │   ├── QtClass.cpp
  │   └── QtClass.h
  └── NamespaceB
      ├── QtClass.cpp
      └── QtClass.h
  

  Finally ：这是基于我个人意见的建议，但是我想建议more explicit version的脚本而不使用 CMAKE_AUTOMOC 和 CMAKE_AUTOUIC ，它更详细，但另一方面你有更多的控制权：

  cmake_minimum_required (VERSION 2.8.12)
  project (MyProject)
  
  find_package (Qt5Widgets)
  
  set (MyProjectLib_src ${PROJECT_SOURCE_DIR}/mainwindow.cpp)
  set (MyProjectLib_hdr ${PROJECT_SOURCE_DIR}/mainwindow.h)
  set (MyProjectLib_ui  ${PROJECT_SOURCE_DIR}/mainwindow.ui)
  set (MyProjectBin_src ${PROJECT_SOURCE_DIR}/main.cpp)
  
  qt5_wrap_cpp(MyProjectLib_hdr_moc ${MyProjectLib_hdr})
  qt5_wrap_ui (MyProjectLib_ui_moc  ${MyProjectLib_ui})
  
  include_directories (${PROJECT_SOURCE_DIR})
  include_directories (${PROJECT_BINARY_DIR})
  
  add_library (MyProjectLib SHARED 
      ${MyProjectLib_src}
      ${MyProjectLib_hdr_moc}
      ${MyProjectLib_ui_moc}
  )
  target_link_libraries (MyProjectLib Qt5::Widgets)
  
  add_executable(MyProject ${MyProjectBin_src})
  target_link_libraries (MyProject MyProjectLib)
  

  项目源代码的完整版本可在GitLab获得 .

  回复于 2024-04-29T04:28:27+08:00
• 0

  您没有告诉我们CMakeLists.txt在目录结构中的位置 . 如果它在顶级那么你会有

  add_executable(Cmake sources/main.cpp sources/mainwindow.cpp)
  

  而且你需要

  include_directories(${CMAKE_CURRENT_SOURCE_DIR}/headers)
  

  无论如何，找出生成ui _ * .h文件的位置，并使用 include_directories 添加目录 .

  回复于 2024-04-29T04:28:27+08:00