使用OpenGL时是否可以在GPU上执行浮点运算？

3 回答

• 1

  OpenGL是否提供了一些API，可以将这些计算“转发”到GPU？

  我会看一下GLSL，OpenGL着色语言 .

  尽管@Jared说过，我认为你可以编程GPU来并行计算Sierpinski地毯，至少可以达到规定的迭代次数 . （在WebGL中尝试这将是一个有趣的项目 . ）

  Edit: 这是使用WebGL的Sierpinski地毯的GPU实现，它基于OpenGL ES 2.0并使用GLSL进行着色器编程 . 如果不相同，OpenGL实现将非常相似 .

  #ifdef GL_ES
  precision highp float;
  #endif
  
  uniform vec2 resolution;
  uniform float time;
  uniform sampler2D tex0;
  
  // Sierpinski carpet
  void main(void)
  {
      ivec2 sectors;
      vec2 coordOrig = gl_FragCoord.xy / resolution.xy;
      const int lim = 5;
  
      /* If you want it to spin, just to prove that it is redrawing
      the carpet every frame: */
      vec2 center = vec2(0.5, 0.5);
      mat2 rotation = mat2(
          vec2( cos(time), sin(time)),
          vec2(-sin(time), cos(time))
      );
      vec2 coordRot = rotation * (coordOrig - center) + center;
      vec2 coordIter = coordRot;
  
      for (int i=0; i < lim; i++) {
          sectors = ivec2(floor(coordIter.xy * 3.0));
          if (sectors.x == 1 && sectors.y == 1 ||
              // rotation can put us out of bounds
              sectors.x < 0 || sectors.x > 2 ||
              sectors.y < 0 || sectors.y > 2) {
              // make a hole
              gl_FragColor = vec4(texture2D(tex0, coordOrig).xyz, 1.0);
  
              return;
          } else {
              // map current sector to whole carpet
              coordIter.xy = coordIter.xy * 3.0 - vec2(sectors.xy);
          }
      }
  
      gl_FragColor = vec4(coordRot.x, 0.5, coordRot.y, 1.0);
  
  }
  

  要对此进行测试，请使用WebGL-enabled browser转到Shader Toy，然后将上述代码粘贴到"Source"窗口中 . 按Alt键输入：Presto！在我的笔记本电脑上，它没有很好的震动，但有一个图形加速卡，它运行在45-60帧/秒 .

  为了获得截图中显示的背景纹理，我将此纹理用于输入下的单元0：http://www.iquilezles.org/apps/shadertoy/presets/tex3.jpg

  正如您所看到的，我将lim（迭代级别数）设置为5 ...在我测试的分辨率下，接近子像素精度 .

  

  所以你的问题的答案，“我想知道OpenGL是否可以使用GPU进行典型的图形计算，比如计算坐标，”肯定是的 . 从技术上讲，上面使用像素着色器，它计算颜色以 生产环境 Sierpinski地毯 . 如果您确实需要调整顶点的坐标，则可以使用顶点着色器 . 这个过程很相似 .

  回复于 2024-04-29T21:57:16+08:00
• 10

  如果您按像素执行此操作，则必须将总线上的坐标发送到GPU，计算新坐标，然后将其发回，然后调用OpenGL命令绘制点等 .

  使用着色器，您可能能够使用Sierpinski地毯，但分形是非常顺序的（至少是通过平均点后计算的典型方式） . 换句话说，您将失去使GPU具有吸引力的并行优势 .

  回复于 2024-04-29T21:57:16+08:00
• 0

  正如其他人所说，你需要使用着色器 . 除了GLSL，您还可以使用Cg .

  回复于 2024-04-29T21:57:16+08:00